_GUICtrlRichEdit_SetCharBkColor
Устанавливает цвет фона выделенного текста или, если не выделено, то устанавливает цвет фона вставляемого текста в позицию курсора
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetCharBkColor($hWnd [, $iColor])
Параметры
| $hWnd | Дескриптор элемента |
| $iColor |
[необязательный] Один из следующих: число COLORREF Ключевое слово Default - системный цвет (по умолчанию) |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False и устанавливает @error |
| @error: | 101 - $HWnd не является дескриптором |
| 1021 - $vColor: отсутствует две точка с запятой | |
| 1022 - $vColor: значение не от 0 до 100 | |
| 1023 - $vColor: недопустимый символ |
Примечания
Если вам нужно создать значение COLORREF из массива значений цвета, то используйте _ColorSetCOLORREF(), а не _ColorSetRGB().См. также
_GUICtrlRichEdit_GetCharBkColorСм. также
Искать EM_SETCHARFORMAT в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Color.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
Report("1. Текущий цвет")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 1, 7)
_GUICtrlRichEdit_SetCharBkColor($hRichEdit, Dec('00FF00'))
Report("2. Изменённый цвет")
Case 3
_GUICtrlRichEdit_SetSel($hRichEdit, 2, 5)
_GUICtrlRichEdit_SetCharBkColor($hRichEdit, Dec('8888FF'))
Report("3. Цвет фона некоторых символов изменился")
Case 4
_GUICtrlRichEdit_SetSel($hRichEdit, 0, -1)
; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
_GUICtrlRichEdit_Deselect($hRichEdit)
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
Report("4. Сохранено в файл gcre.rtf на рабочий стол")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
Local $iBkColor = _GUICtrlRichEdit_GetCharBkColor($hRichEdit)
Local $sMixed = _Iif(@extended, "+", "~")
Local $aRet = _ColorGetRGB($iBkColor)
$sMsg &= @cr & @cr & $aret[0] & ";" & $aret[1] & ";" & $aret[2] & " bkcolor=0x" & Hex($iBkColor) & ":" & $sMixed
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report