↑  ←  Описание функции

_GUICtrlRichEdit_ResumeRedraw

Возобновляет перерисовку элемента

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ResumeRedraw($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором

См. также

_GUICtrlRichEdit_PauseRedraw

См. также

Искать WM_SETREDRAW в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_PauseRedraw($hRichEdit)
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 5, 2)
                        GUICtrlSetData($lblMsg, "1. Перерисовка элемента приостановлена")
                    Case 2
                        _GUICtrlRichEdit_InsertText($hRichEdit, "ВСТАВКА_2")
                        GUICtrlSetData($lblMsg, "2. Текст вставлен в позицию выделенного текста")
                    Case 3
                        _GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
                        _GUICtrlRichEdit_InsertText($hRichEdit, "ВСТАВКА_3")
                        GUICtrlSetData($lblMsg, "3. Текст вставлен в позицию курсора и возобновлена перерисовка")
                        _GUICtrlRichEdit_ResumeRedraw($hRichEdit)
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main