↑  ←  Описание функции

_GUICtrlRichEdit_HideSelection

Скрыть (или показать) выделение

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_HideSelection($hWnd [, $fHide = True])

Параметры

$hWnd Дескриптор элемента
$fHide [необязательный] True - Скрыть
False - Показать
Default: Скрыть

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $fHide не является True или False

См. также

Искать EM_HIDESELECTION в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
OnAutoItExitRegister('_OnExit') ; Освобождает ресурсы RichEdit даже при завершении скрипта с ошибкой

$hGui = GUICreate("Скрыть / показать выделенное", 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Тест: Показать или скрыть выделенный текст", 10, 10, 400, 220, _
        BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
GUISetState()

; Выделяет текст
_GUICtrlRichEdit_SetSel($hRichEdit, 5, -1)
Sleep(500)
; Скрывает
_GUICtrlRichEdit_HideSelection($hRichEdit, True)
Sleep(500)
; Отображает
_GUICtrlRichEdit_HideSelection($hRichEdit, False)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _OnExit()
    ; Для версий ниже 3.3.8.0 обязательно удаление RichEdit или GUI для освобождения ресурсов RichEdit
    _GUICtrlRichEdit_Destroy($hRichEdit)
    GUIDelete()
EndFunc