↑  ←  Описание функции

_GUICtrlRichEdit_GetXYFromCharPos

Возвращает координаты (X, Y) межсимвольной позиции.

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetXYFromCharPos($hWnd, $iCharPos)

Параметры

$hWnd Дескриптор элемента
$iCharPos Межсимвольная позиция

Возвращаемое значение

Успех:Возвращает координаты межсимвольной позиции в виде массива [, ], относительно левого верхнего угла клиентской области
Ошибка:устанавливает @error
@error:101 - $HWnd не является дескриптором
1021 - $iCharPos не является положительным числом или нулём
1022 - $iCharPos превышает количество символов в элементе

Примечания

Первая межсимвольная позиция начинается с 0

В многострочном элементе, координаты возвращаются даже для межсимвольной позиции, которая не видна (не находится в видимой области окна).

См. также

_GUICtrlRichEdit_GetCharPosFromXY

См. также

Искать EM_POSFROMCHAR в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $ai, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & 'Добавленный текст.')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $ai = _GUICtrlRichEdit_GetXYFromCharPos($hRichEdit, 20)
                        GUICtrlSetData($lblMsg, "1. Координаты межсимвольной позиции 20: (" & $ai[0] & "," & $ai[1] & ")")
                        _GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
                    Case 2
                        GUICtrlSetData($lblMsg, "2.Межсимвольная позиция ближайшая к координатам (" & $ai[0] & "," & $ai[1] & ") равна " & _
                                _GUICtrlRichEdit_GetCharPosFromXY($hRichEdit, $ai[0], $ai[1]))
                        _GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc