↑  ←  Описание функции

_GUICtrlRichEdit_GetSel

Возвращает начальную и конечную позицию выделенного текста

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSel($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает массив в формате [<меньшее>, <большее>]
Ошибка:устанавливает @error
@error:101 - $HWnd не является дескриптором

Примечания

Первый символ текста в элементе имеет позицию 0
Если начальная и конечная позиции равны, значит текст не выделен

См. также

_GUICtrlRichEdit_SetSel, _GUICtrlRichEdit_GetSelText, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_GetTextInLine, _GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_IsTextSelected

См. также

Искать EM_EXGETSEL в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetSel($hRichEdit, 2 , 10)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Текст выделен между указанных позиций")
                    Case 2
                        _GUICtrlRichEdit_DeSelect($hRichEdit)
                        Report("2. Теперь текст не выделен")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aPos  = _GUICtrlRichEdit_GetSel($hRichEdit)
    $sMsg &=  @CR & @CR & "Позиции: " & $aPos[0] & ", "  & $aPos[1]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report