_GUICtrlRichEdit_GetParaBorder
Gets the border settings of (first) selected paragraph or (if no selection) of the current paragraph
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaBorder($hWnd)
Параметры
| $hWnd | Дескриптор элемента |
Возвращаемое значение
| Успех: | settings of first selected paragraph - a string consisting of values separated by semicolons (:): | |
| Value 1 | one or more of: | |
| l - left border | ||
| r - right border | ||
| t - top border | ||
| b - bottom border | ||
| i - inside border | ||
| o - outside border | ||
| or empty - no border | ||
| Value 2 - line style - one of: | ||
| none - no line | ||
| .75 - 3/4 point | ||
| 1.5 - 1 1/2 points | ||
| 2.25 - 2 1/4 points | ||
| 3 - 3 points | ||
| 4.5 - 4 1/2 points | ||
| 6 - 6 points | ||
| .75d - 1/2 points, double | ||
| 1.5d - 1 1/2 points, double | ||
| 2.25d - 2 1/4 points, double | ||
| .75g - 3/4 point grey | ||
| .75gd - 3/4 point grey dashed | ||
| Value 3 - one of: | ||
| aut - autocolor | ||
| blk - black | ||
| blu - blue | ||
| cyn - cyan | ||
| grn - green | ||
| mag - magenta | ||
| red - red | ||
| yel - yellow | ||
| whi - white | ||
| dbl - dark blue | ||
| dgn - dark green | ||
| dmg - dark magenta | ||
| drd - dark red | ||
| dyl - dark yellow | ||
| dgy - dark grey | ||
| lgy - light grey | ||
| Value 4 - space between the border and the text (in space units) | ||
| Value 5 - scope: | ||
| a - all (or only) selected paragraphs have these settings | ||
| f - the first selected paragraph has these settings, but other(s) don't | ||
| c - the current paragraph has these settings | ||
| Ошибка: | Возвращает "" - пустую строку и устанавливает @error | |
| @error: | 101 - $hWnd is not a handle |
Примечания
Borders do not show in Rich Edit, but borders created here will show in WordСм. также
_GUICtrlRichEdit_SetParaBorderСм. также
Искать EM_GETPARAFORMAT в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iStep = 0, $btnNext
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
_GUICtrlRichEdit_AppendText($hRichEdit, "First paragraph")
Report("0. First paragraph: default settings")
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaBorder($hRichEdit, "o", 3, "mag", 0.25)
Report("1. Second paragraph: with border (should show in Word)")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 10, -1)
Report("2. Settings of first paragraph in selection")
Case 3
_GUICtrlRichEdit_SetParaBorder($hRichEdit, "l", 6, "blu")
Report("3. Settings of both paragraphs changed")
Case 4
_GUICtrlRichEdit_SetParaBorder($hRichEdit, Default, ".75gd")
Report("4. Line style changed")
Case 5
; Stream all text to the Desktop so you can look at border settings in Word
_GUICtrlRichEdit_Deselect($hRichEdit)
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg &= @cr & @cr & "get function returns " & @cr & _GUICtrlRichEdit_GetParaBorder($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report