_GUICtrlRichEdit_GetParaAttributes
Gets the attributes of (first) selected paragraph or (if no selection) of the current paragraph
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaAttributes($hWnd)
Параметры
| $hWnd | Дескриптор элемента |
Возвращаемое значение
| Успех: | a string consisting of values separated by semicolons ";". |
| Values 1 to 10: a group consisting of: | |
| Characters 1 to 3 - attribute | |
| fpg - force this/these paragraphs on to new page(s) (Initially off) | |
| hyp - automatic hypthenation (Initially on) | |
| kpt - keep this/these paragraph(s) together on a page (Initially off} | |
| kpn - keep this/these paragraph(s) and the next together on a page (Initially off) | |
| pwo - prevent widows and orphans, i.e. avoid a single line of this/these paragraph(s) | |
| on a page (Initially off) | |
| r2l - display text using right-to-left reading order (Initially off) | |
| sbs - display paragraphs side by side (Initially off) | |
| sln - suppress line numbers in documents or sections with line numbers (Initially off) | |
| tbl - paragraph(s) is/are table row(s) (Initially off) | |
| Character 4 - state: | |
| + - attribute is on | |
| - - attribute is off | |
| Value 11 - scope: | |
| f - the first selected paragraph has these attributes | |
| c - the current paragraph has these attributes | |
| Ошибка: | Возвращает "" - пустую строку и устанавливает @error |
| @error: | 101 - $hWnd is not a handle |
См. также
_GUICtrlRichEdit_SetParaAttributesСм. также
Искать EM_SETPARAFORMAT в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
_GUICtrlRichEdit_AppendText($hRichEdit, "First paragraph")
Report("First paragraph: default attributes")
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaAttributes($hRichEdit, "-hyp")
Report("Second paragraph: hyphenation off")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 10, -1)
_GUICtrlRichEdit_SetParaAttributes($hRichEdit, "-hyp;+fpg;+kpn")
Report("Attributes of first paragraph in selection")
Case 3
; Stream all text to the Desktop so you can look at attributes in Word
_GUICtrlRichEdit_Deselect($hRichEdit)
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg &= @cr & @cr & "get function returns " & @cr & _GUICtrlRichEdit_GetParaAttributes($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report