↑  ←  Описание функции

_GUICtrlRichEdit_GetNumberOfFirstVisibleLine

Возвращает номер первой строки, которая видна в элементе

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetNumberOfFirstVisibleLine($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает номер строки (отсчёт от 1)
Ошибка:Возвращает 0 и устанавливает @error
@error:101 - $HWnd не является дескриптором

Примечания

Первая строка имеет номер 1

См. также

Искать EM_GETFIRSTVISIBLELINE в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    For $i = 2 To 50
        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Line " & $i)
    Next

    Report("First visible line is number " & _GUICtrlRichEdit_GetNumberOfFirstVisibleLine($hRichEdit))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report