↑  ←  Описание функции

_GUICtrlRichEdit_GetNextUndo

Retrieves the name or type ID of the next possible Undo action

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetNextUndo($hWnd, $fName = True)

Параметры

$hWnd Дескриптор элемента
$fName True (return name, default) or False (return ID number)

Возвращаемое значение

Успех:depends on value of $fName:
If $fName is True: "Unknown", "Typing", "Delete", "Drag and drop", "Cut" or "Paste"
If $Name is False: the corresponding number (0 to 5)
Ошибка:Возвращает "" - пустую строку и устанавливает @error
@error:101 - $hWnd is not a handle
102 - $fName is neither True nor False

Примечания

Note that EM_GETUNDONAME does not distinguish between Unknown and Undo queue empty

См. также

_GUICtrlRichEdit_Undo, _GUICtrlRichEdit_Undo

См. также

Искать EM_GETUNDONAME в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiMenu.au3>

Global $hRichEdit, $mnu, $mnuUndo, $mnuRedo, $mnuCut, $mnuCopy
Global $mnuPaste, $mnuPasteSpl, $mnuPasteSplRTF, $mnuPasteSplwObjs

Main()

Func Main()
    Local $hGui
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Это тест.", 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, ReadBmpToRtf(FindFirstBMP()) & @CR)

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    $mnu = GUICtrlCreateContextMenu(GUICtrlCreateDummy())
    $mnuUndo = GUICtrlCreateMenuItem("Отмена", $mnu)
    $mnuRedo = GUICtrlCreateMenuItem("Повтор", $mnu)
    GUICtrlCreateMenuItem("", $mnu)
    $mnuCut = GUICtrlCreateMenuItem("Вырезать", $mnu)
    $mnuCopy = GUICtrlCreateMenuItem("Копировать", $mnu)
    $mnuPaste = GUICtrlCreateMenuItem("Вставить", $mnu)
    $mnuPasteSpl = GUICtrlCreateMenu("Специальная вставка", $mnu)
    $mnuPasteSplRTF = GUICtrlCreateMenuItem("Только RTF", $mnuPasteSpl)
    $mnuPasteSplwObjs = GUICtrlCreateMenuItem("С объектами", $mnuPasteSpl)
    _GUICtrlRichEdit_SetEventMask($hRichEdit, $ENM_MOUSEEVENTS)

    While True
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $mnuUndo
                _GUICtrlRichEdit_Undo($hRichEdit)
            Case $mnuRedo
                _GUICtrlRichEdit_Redo($hRichEdit)
            Case $mnuCut
                _GUICtrlRichEdit_Cut($hRichEdit)
            Case $mnuCopy
                _GUICtrlRichEdit_Copy($hRichEdit)
            Case $mnuPaste
                _GUICtrlRichEdit_Paste($hRichEdit)
            Case $mnuPasteSplRTF
                _GUICtrlRichEdit_PasteSpecial($hRichEdit, False)
            Case $mnuPasteSplwObjs
                _GUICtrlRichEdit_PasteSpecial($hRichEdit, True)
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
    #forceref $iMsg, $iWparam
    Local $hWndFrom, $iCode, $tNMHDR, $tMsgFilter, $hMenu
    $tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hRichEdit
            Select
                Case $iCode = $EN_MSGFILTER
                    $tMsgFilter = DllStructCreate($tagMSGFILTER, $iLparam)
                    If DllStructGetData($tMsgFilter, "msg") = $WM_RBUTTONUP Then
                        $hMenu = GUICtrlGetHandle($mnu)
                        _SetMenuTexts($hWndFrom, $hMenu)
                        _GUICtrlMenu_TrackPopupMenu($hMenu, $hWnd)
                    EndIf
            EndSelect
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _SetMenuTexts($hWnd, $hMenu)
    Local $fState
    If _GUICtrlRichEdit_CanUndo($hWnd) Then
        _GUICtrlMenu_SetItemEnabled($hMenu, $mnuUndo, True, False)
        _GUICtrlMenu_SetItemText($hMenu, $mnuUndo, "Отмена: " & _GUICtrlRichEdit_GetNextUndo($hWnd), False)
    Else
        _GUICtrlMenu_SetItemText($hMenu, $mnuUndo, "Отмена", False)
        _GUICtrlMenu_SetItemEnabled($hMenu, $mnuUndo, False, False)
    EndIf
    If _GUICtrlRichEdit_CanRedo($hWnd) Then
        _GUICtrlMenu_SetItemEnabled($hMenu, $mnuRedo, True, False)
        _GUICtrlMenu_SetItemText($hMenu, $mnuRedo, "Повтор: " & _GUICtrlRichEdit_GetNextRedo($hWnd), False)
    Else
        _GUICtrlMenu_SetItemText($hMenu, $mnuRedo, "Повтор", False)
        _GUICtrlMenu_SetItemEnabled($hMenu, $mnuRedo, False, False)
    EndIf
    $fState = _GUICtrlRichEdit_IsTextSelected($hWnd)
    _GUICtrlMenu_SetItemEnabled($hMenu, $mnuCut, $fState, False)
    _GUICtrlMenu_SetItemEnabled($hMenu, $mnuCopy, $fState, False)

    _GUICtrlMenu_SetItemEnabled($hMenu, $mnuPaste, _GUICtrlRichEdit_CanPaste($hWnd))

    _GUICtrlMenu_SetItemEnabled($hMenu, $mnuPasteSpl, _GUICtrlRichEdit_CanPasteSpecial($hWnd), False)
EndFunc   ;==>_SetMenuTexts

Func ReadBmpToRtf($sBmpFilspc)
    Local $hFile, $sRtf
    $hFile = FileOpen($sBmpFilspc, 16)
    If FileRead($hFile, 2) <> "0x424D" Then Return SetError(1, 0, "")
    FileRead($hFile, 12)
    $sRtf = '{\rtf1{\pict\dibitmap ' & Hex(FileRead($hFile)) & '}}'
    FileClose($hFile)
    Return $sRtf
EndFunc   ;==>ReadBmpToRtf

Func FindFirstBMP($sPath = @WindowsDir)
    Local $hFind, $sBmpFilspc
    $hFind = FileFindFirstFile($sPath & "\*.bmp")
    $sBmpFilspc = FileFindNextFile($hFind)
    FileClose($hFind)
    Return $sPath & "\" & $sBmpFilspc
EndFunc   ;==>FindFirstBMP