↑  ←  Описание функции

_GUICtrlRichEdit_GetCharPosOfNextWord

Возвращает межсимвольную позицию перед следующим словом

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharPosOfNextWord($hWnd, $iCpStart)

Параметры

$hWnd Дескриптор элемента
$iCPStart Межсимвольная позиция, от которой начинать

Возвращаемое значение

Успех:Возвращает межсимвольную позицию перед следующим словом
Ошибка:Возвращает 0 и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $iCpStart не является числом

Примечания

"Слово" определяется в широком смысле; оно включает в себя знаки препинания, скобки и дефисы.

См. также

_GUICtrlRichEdit_GetCharPosOfPreviousWord, _GUICtrlRichEdit_GetCharWordBreakInfo

См. также

Искать EM_FINDWORDBREAK в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $btnNext, $iCp = 0, $lblMsg, $hRichEdit
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & 'Следите за перемещением ' & _
            'текстового курсора при нажатии кнопки "Далее".')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iCp = _GUICtrlRichEdit_GetCharPosOfNextWord($hRichEdit, $iCp)
                GUICtrlSetData($lblMsg, $iCp)
                ControlFocus($hRichEdit, "", "")
                _GUICtrlRichEdit_GotoCharPos($hRichEdit, $iCp)
        EndSwitch
    WEnd
EndFunc