↑  ←  Описание функции

_GUICtrlRichEdit_GetCharColor

Возвращает цвет выделенного текста или, если нет выделения, то цвет символа справа от курсора

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharColor($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает цвет COLORREF, @extended = 1, если цвет same throught the selection
Ошибка:устанавливает @error
@error:101 - $HWnd не является дескриптором

Примечания

Если вам нужно создать массив значений цвета, то используйте _ColorGetCOLORREF(), а не _ColorGetRGB().

См. также

_GUICtrlRichEdit_SetCharColor

См. также

Искать EM_GETCHARFORMAT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Color.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Текущий цвет")
                    Case 2
                        _GUICtrlRichEdit_SetCharColor($hRichEdit, Dec('009900'))
                        Report("2. Изменённый цвет")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 1, 5)
                        _GUICtrlRichEdit_SetCharColor($hRichEdit, Dec('0000FF'))
                        Report("3. Цвет некоторых символов изменился")
                    Case 4
                        ; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        Report("4. Сохранено в файл gcre.rtf на рабочий стол")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $iColor  = _GUICtrlRichEdit_GetCharColor($hRichEdit)
    Local $aRet = _ColorGetRGB($iColor)
    $sMsg &=  @cr & @cr & $aret[0] & ";" & $aret[1] & ";" & $aret[2] & " color=0x" & Hex($iColor)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report