↑  ←  Описание функции

_GUICtrlRichEdit_AutoDetectURL

Включение или отключение автоматического определения гиперссылок интернета (URL)

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_AutoDetectURL($hWnd, $fState)

Параметры

$hWnd Дескриптор элемента
$fState True для обнаружения всех ссылок в тексте, False для отключения обнаружения

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $fState не является True или False
700 - внутренняя ошибка, например, недостаточно памяти

Примечания

Если состояние установлено, то любая модификация текста приводит к проверке текста на соответствие URL-формату. Распознаются строки начинающиеся со следующих URL-адресов, таких как: http:, file:, mailto:, ftp:, https:, gopher:, nntp:, prospero:,telnet:, news:, wais:. При обнаружении URL, Windows устанавливает атрибуты ссылки для всех символов URL-адреса, и подчеркивает строку.

При автоматическом обнаружении URL и URL найден, то Windows удаляет атрибуты ссылок со всех символов, которые не являются URL-адресом.

Для уведомительных сообщений, используйте функцию _GUICtrlRichEdit_SetEventMask с $ENM_LINK

См. также

_GUICtrlRichEdit_SetEventMask

См. также

Искать EM_AUTOURLDETECT в библиотеке MSDN, Искать EN_LINK notification в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $hRichEdit

Main()

Func Main()
    Local $hGui
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
    _GUICtrlRichEdit_SetEventMask($hRichEdit, $ENM_LINK)

    _GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "http://www.autoitscript.com")
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
    #forceref $hWnd, $iMsg, $iWparam
    Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $cpMin, $cpMax, $tMsgFilter
    $tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hRichEdit
            Select
                Case $iCode = $EN_LINK
                    $tMsgFilter = DllStructCreate($tagMSGFILTER, $iLparam)
                    If DllStructGetData($tMsgFilter, "msg") = $WM_LBUTTONUP Then
                        $tEnLink = DllStructCreate($tagENLINK, $iLparam)
                        $cpMin = DllStructGetData($tEnLink, "cpMin")
                        $cpMax = DllStructGetData($tEnLink, "cpMax")
                        MsgBox(4096, "", "Здесь вызов вашего веб-браузера открывающего ссылку " & _
                                _GUICtrlRichEdit_GetTextInRange($hRichEdit, $cpMin, $cpMax))
                    EndIf
            EndSelect
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY