_GUICtrlMonthCal_SetSelRange
Выделяет указанный диапазон
#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetSelRange($hWnd, $iMinYear, $iMinMonth, $iMinDay, $iMaxYear, $iMaxMonth, $iMaxDay)
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $iMinYear |
Минимальный год |
| $iMinMonth |
Минимальный месяц |
| $iMinDay |
Минимальный день |
| $iMaxYear |
Максимальный год |
| $iMaxMonth |
Максимальный месяц |
| $iMaxDay |
Максимальный день |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
Примечания
Это не сработает, если применяется к элементу календаря, который не использует стиль $MCS_MULTISELECTСм. также
_GUICtrlMonthCal_GetSelRangeПример
#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
$Debug_MC = False ; Проверяет ClassName передаваемый в MonthCal функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $tRange, $hMonthCal
; Создаёт GUI
GUICreate("Выделяет указанный диапазон", 400, 300)
$hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)
; Создаёт элемент для заметок
$iMemo = GUICtrlCreateEdit("", 4, 188, 392, 108, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Установить / получить выделенное
_GUICtrlMonthCal_SetSelRange($hMonthCal, @YEAR, @MON, 1, @YEAR, @MON, 7)
$tRange = _GUICtrlMonthCal_GetSelRange($hMonthCal)
MemoWrite("Нижняя дата : " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MinMonth"), _
DllStructGetData($tRange, "MinDay"), _
DllStructGetData($tRange, "MinYear")))
MemoWrite("Верхняя дата : " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MaxMonth"), _
DllStructGetData($tRange, "MaxDay"), _
DllStructGetData($tRange, "MaxYear")))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite