↑  ←  Описание функции

_GUICtrlMonthCal_SetColor

Устанавливает цвет указанного участка элемента

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetColor($hWnd, $iIndex, $iColor)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Указывает, цвет какого участка элемента необходимо установить:
    $MCSC_BACKGROUND - Цвет фона между месяцами
    $MCSC_TEXT - Цвет текста дней указанного месяца
    $MCSC_TITLEBK - Цвет фона в заголовке календаря и выбранный день
    $MCSC_TITLETEXT - Цвет текста в заголовке календаря и выбранный день
    $MCSC_MONTHBK - Цвет фона месяцев
    $MCSC_TRAILINGTEXT - Цвет текста для дней, которые не принадлежат указанному месяцу
$iColor Цвет (BGR), который будет установлен для указанного участка

Возвращаемое значение

Успех:Возвращает предыдущий цвет указанного участка
Ошибка:Возвращает -1

См. также

_GUICtrlMonthCal_GetColor

Пример

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_MC = False ; Проверяет ClassName передаваемый в MonthCal функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hMonthCal

    ; Создаёт GUI
    GUICreate("Устанавливает цвет элементов", 400, 300)
    $hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Создаёт элемент для заметок
    $iMemo = GUICtrlCreateEdit("", 4, 188, 392, 108, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Установить / получить цвет элементов календаря
    MemoWrite("Фон: 0x" & Hex(_GUICtrlMonthCal_GetColor($hMonthCal, $MCSC_MONTHBK), 6))

    ; _GUICtrlMonthCal_SetColor($hMonthCal, $MCSC_MONTHBK, $CLR_MONEYGREEN)
    _GUICtrlMonthCal_SetColor($hMonthCal, $MCSC_TEXT, 0x8BD4DF) ; текст дней
    _GUICtrlMonthCal_SetColor($hMonthCal, $MCSC_TITLEBK, 0xA9D7E4) ; фон заголовка
    _GUICtrlMonthCal_SetColor($hMonthCal, $MCSC_TITLETEXT, 0x005894) ; текст заголовка
    _GUICtrlMonthCal_SetColor($hMonthCal, $MCSC_MONTHBK, 0x3F3F3F) ; фон календаря
    _GUICtrlMonthCal_SetColor($hMonthCal, $MCSC_TRAILINGTEXT, 0xB2C2A9) ; текст дней не принадлежащих месяцу

    MemoWrite("Фон: 0x" & Hex(_GUICtrlMonthCal_GetColor($hMonthCal, $MCSC_MONTHBK), 6))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite