↑  ←  Описание функции

_GUICtrlMonthCal_SetCalendarBorder

Устанавливает размер границ, в пикселях

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetCalendarBorder($hWnd [, $iBorderSize = 4 [, $fSetBorder = True]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iBorderSize [необязательный] Число пикселей, являющееся размером границы
$fSetBorder [необязательный] Одно из следующих:
    True - Размер границы устанавливается тот, что указан в параметре $iBorderSize     False - Размер границы сбрасывается в значение по умолчанию, определяемое темой, или в ноль, если темы не используются

Примечания


Минимальная ОС: Windows Vista

См. также

_GUICtrlMonthCal_GetCalendarBorder

Пример

If @osversion = "WIN_XP" And MsgBox(4160 + 4 + 256, "Информация", "Эта функция не работает в WinXP" & @lf & "продолжить?") = 7 Then Exit
#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_MC = False ; Проверяет ClassName передаваемый в MonthCal функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hMonthCal

    ; Создаёт GUI
    GUICreate("Календарь месяца", 400, 300)
    $hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Создаёт элемент для заметок
    $iMemo = GUICtrlCreateEdit("", 4, 188, 392, 108, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Установить / получить размер границ календаря
    MemoWrite("Граница в пикселях: " & _GUICtrlMonthCal_GetCalendarBorder($hMonthCal))
    Sleep(3000)
    GUISetState(@SW_LOCK)
    _GUICtrlMonthCal_SetCalendarBorder($hMonthCal, 2)
    MemoWrite("Граница в пикселях: " & _GUICtrlMonthCal_GetCalendarBorder($hMonthCal))
    GUISetState(@SW_UNLOCK)
    Sleep(3000)
    GUISetState(@SW_LOCK)
    _GUICtrlMonthCal_SetCalendarBorder($hMonthCal, 0, False)
    MemoWrite("Граница в пикселях: " & _GUICtrlMonthCal_GetCalendarBorder($hMonthCal))
    GUISetState(@SW_UNLOCK)


    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite