_GUICtrlMonthCal_GetMonthRange
Возвращает отображаемый диапазон месяца, верхнюю и нижнюю дату
#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMonthRange($hWnd [, $fPartial = False])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $fPartial |
[необязательный] Определяет пределы диапазона возвращаемой области: True - Включая отображаемые дни предыдущего и последующего месяца False - Только дни текущего месяца |
Возвращаемое значение
Успех: Возвращает структуру $tagMCMONTHRANGEСм. также
_GUICtrlMonthCal_GetMonthRangeMax, _GUICtrlMonthCal_GetMonthRangeMin, $tagMCMONTHRANGEПример
#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
$Debug_MC = False ; Проверяет ClassName передаваемый в MonthCal функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $tRange, $hMonthCal
; Создаёт GUI
GUICreate("Получает отображаемый диапазон", 400, 300)
$hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)
; Создаёт элемент для заметок
$iMemo = GUICtrlCreateEdit("", 4, 188, 392, 108, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Получает отображаемый диапазон
$tRange = _GUICtrlMonthCal_GetMonthRange($hMonthCal)
MemoWrite("Нижняя дата диапазона: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MinMonth"), _
DllStructGetData($tRange, "MinDay"), _
DllStructGetData($tRange, "MinYear")))
MemoWrite("Верхняя дата диапазона: " & StringFormat("%02d/%02d/%04d", DllStructGetData($tRange, "MaxMonth"), _
DllStructGetData($tRange, "MaxDay"), _
DllStructGetData($tRange, "MaxYear")))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite