↑  ←  Описание функции

_GUICtrlListView_SetItemPosition32

Перемещает пункт в указанную позицию внутри ListView

#include <GuiListView.au3>
_GUICtrlListView_SetItemPosition32($hWnd, $iIndex, $iCX, $iCY)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта
$iCX Новая x-координата пункта верхнего левого угла
$iCY Новая y-координата пункта верхнего левого угла

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если ListView имеет стиль $LVS_AUTOARRANGE, то пункты упорядочиваются после изменения позиции пункта. ListView должен иметь вид "icon" или "small icon".

Эта функция отличается от функции _GUICtrlListView_SetItemPosition тем, что использует 32-битные координаты.

См. также

_GUICtrlListView_SetItemPosition

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("Перемещает пункт в позицию", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Пункт " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Устанавливает вид "Small Icon"
    _GUICtrlListView_SetView($hListView, 3)
    MsgBox(4160, "Информация", "Перемещает 2-ой пункт")
    _GUICtrlListView_SetItemPosition32($hListView, 1, 100, 100)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main