↑  ←  Описание функции

_GUICtrlListView_SetHoverTime

Устанавливает интервал времени, между наведением курсора мыши на пункт и его авто-выделением.

#include <GuiListView.au3>
_GUICtrlListView_SetHoverTime($hWnd, $iTime)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iTime Новое значение интервала времени в миллисекундах, между наведением курсора мыши на пункт и его авто-выделением. Если это значение (DWORD)-1, то интервал устанавливается на значение по умолчанию.

Возвращаемое значение

Возвращает предыдущий интервал времени

Примечания

Интервал времени влияет только на ListView со стилями $LVS_EX_TRACKSELECT,
$LVS_EX_ONECLICKACTIVATE или $LVS_EX_TWOCLICKACTIVATE

См. также

_GUICtrlListView_GetHoverTime

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hListView, $Status

_Main()

Func _Main()
    Local $GUI
    Local $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES, $LVS_EX_TRACKSELECT)

    $GUI = GUICreate("Устанавливает время наведения", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetHoverTime($hListView, 1000)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
    $hListView = GUICtrlGetHandle($hListView)
    $Status = _GUICtrlStatusBar_Create($GUI, -1, "")
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 100)

    _GUICtrlListView_InsertItem($hListView, "Стр 1: Кол 1")
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
    _GUICtrlListView_InsertItem($hListView, "Стр 2: Кол 1")
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
    _GUICtrlListView_InsertItem($hListView, "Стр 3: Кол 1")

    ; Получает время наведения
    MsgBox(4160, "Информация", "Предыдущее время наведения (миллисекунд): " & _GUICtrlListView_GetHoverTime($hListView))

    ; Устанавливает время наведения
    _GUICtrlListView_SetHoverTime($hListView, 500)
    MsgBox(4160, "Информация", "Время наведения (миллисекунд): " & _GUICtrlListView_GetHoverTime($hListView))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>_Main

Func ListView_HOTTRACK($iSubItem)
    Local $HotItem = _GUICtrlListView_GetHotItem($hListView)
    If $HotItem <> -1 Then _GUICtrlStatusBar_SetText($Status, @TAB & "Горячий пункт: " & $HotItem & " Подпункт: " & $iSubItem)
EndFunc   ;==>ListView_HOTTRACK

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_COLUMNCLICK ; Клик на заголовке колонки
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
                    _DebugPrint("$LVN_COLUMNCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param"))
                    ; Нет возвращаемых значений
                Case $LVN_HOTTRACK ; Высылает в ListView, когда пользователь перемещает курсор мыши над пунктом
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
                    _DebugPrint("$LVN_HOTTRACK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param"))
                    ListView_HOTTRACK(DllStructGetData($tInfo, "SubItem"))
                    Return 0 ; Позволяет ListView выполнить свою процесс отслеживания.
                    ;Return 1 ; Пункт не будет выбран.
                Case $LVN_KEYDOWN ; Клавиша была нажата
                    $tInfo = DllStructCreate($tagNMLVKEYDOWN, $ilParam)
                    _DebugPrint("$LVN_KEYDOWN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->VKey:" & @tab & DllStructGetData($tInfo, "VKey") & @LF & _
                            "-->Flags:" & @tab & DllStructGetData($tInfo, "Flags"))
                    ; Нет возвращаемых значений
                Case $NM_CLICK ; Высылается элементом ListView, когда пользователь кликает пункт левой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_CLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_DBLCLK ; Высылается элементом ListView, когда пользователь делает двойной клик на пункте левой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_KILLFOCUS ; Элемент потерял фокус ввода
                    _DebugPrint("$NM_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $NM_RCLICK ; Высылается элементом ListView, когда пользователь кликает пункт правой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_RCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ;Return 1 ; не разрешает обработку по умолчанию
                    Return 0 ; разрешает обработку по умолчанию
                Case $NM_RDBLCLK ; Высылается элементом ListView, когда пользователь делает двойной клик на пункте правой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_RDBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_RETURN ; Элемент имеет фокус ввода и пользователь нажал клавишу ENTER
                    _DebugPrint("$NM_RETURN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $NM_SETFOCUS ; Элемент получил фокус ввода
                    _DebugPrint("$NM_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint