↑  ←  Описание функции

_GUICtrlListView_SetColumnOrderArray

Устанавливает порядок колонок слева направо

#include <GuiListView.au3>
_GUICtrlListView_SetColumnOrderArray($hWnd, $aOrder)

Параметры

$hWnd Дескриптор или идентификатор элемента
$aOrder Массив целых чисел, который содержит значения индексов колонок в ListView. Массив должен быть следующего формата:
    [0] - количество элементов в массиве
    [1] - индекс первой колонки
    [2] - индекс второй колонки
    [n] - индекс последней колонки

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListView_GetColumnOrder, _GUICtrlListView_GetColumnOrderArray, _GUICtrlListView_SetColumnOrder

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $a_order[5] = [4, 3, 2, 0, 1], $hListView

    GUICreate("Устанав. порядок колонок массивом", 400, 300)
    $hListView = GUICtrlCreateListView("Колонка 1|Колонка 2|Колонка 3|Колонка 4", 2, 2, 394, 268)
    GUISetState()

    ; Устанавливает порядок колонок
    MsgBox(4160, "Информация", "Изменяет порядок колонок")
    _GUICtrlListView_SetColumnOrderArray($hListView, $a_order)

    ; Показывает порядок колонок
    $a_order = _GUICtrlListView_GetColumnOrderArray($hListView)
    MsgBox(4160, "Информация", StringFormat("Порядок колонок: [%d, %d, %d, %d]", $a_order[1], $a_order[2], $a_order[3], $a_order[4]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main