↑  ←  Описание функции

_GUICtrlListView_GetViewRect

Возвращает прямоугольник, обрамляющий все пункты в ListView

#include <GuiListView.au3>
_GUICtrlListView_GetViewRect($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - X координата верхнего левого угла прямоугольника
        [1] - Y координата верхнего левого угла прямоугольника
        [2] - X координата правого нижнего угла прямоугольника
        [3] - Y координата правого нижнего угла прямоугольника

Примечания

Элемент ListView должен быть в стиле иконок или маленьких иконок

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aRect, $hListView

    GUICreate("Получает прямоугольник пунктов", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Пункт " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Устанавливает вид
    _GUICtrlListView_SetView($hListView, 3)

    ; Получает прямоугольник пунктов
    $aRect = _GUICtrlListView_GetViewRect($hListView)
    MsgBox(4160, "Информация", StringFormat("Прямоугольник пунктов: [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main