↑  ←  Описание функции

_GUICtrlListView_GetView

Возвращает текущий вид отображения пунктов в ListView

#include <GuiListView.au3>
_GUICtrlListView_GetView($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает текущий вид:
0 - Details - Таблица, с вертикальным ползунком, сверху вниз.
1 - Large Icon - Большие иконки, 32х32, количество колонок определяется шириной ListView, слева направо с продолжением списка в новой строке.
2 - List - Список, с горизонтальным ползунком, количество строк в колонке определяется высотой ListView, сверху вниз с продолжением списка в новой колонке
3 - Small Icon - Маленькие иконки, вертикальный список с иконками 16х16 слева от текста, сверху вниз.
4 - Tile - Плитка, количество колонок определяется шириной ListView, слева направо с продолжением списка в новой строке.
Ошибка:Возвращает -1

Примечания

Минимальная ОС - Windows XP.

См. также

_GUICtrlListView_SetView, _GUICtrlListView_GetViewDetails, _GUICtrlListView_GetViewLarge, _GUICtrlListView_GetViewList, _GUICtrlListView_GetViewSmall, _GUICtrlListView_GetViewTile

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView - Получает вид", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Пункт " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Устанавливает вид
    MsgBox(4160, "Информация", "Вид: " & _GUICtrlListView_GetView($hListView))
    _GUICtrlListView_SetView($hListView, 4)
    MsgBox(4160, "Информация", "Вид: " & _GUICtrlListView_GetView($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main