↑  ←  Описание функции

_GUICtrlListView_Destroy

Удаляет ListView

#include <GuiListView.au3>
_GUICtrlListView_Destroy(ByRef $hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает True, устанавливает дескриптор равным 0
Ошибка:Возвращает False

Примечания

Ограничение: применяется только к элементу ListView, созданному функцией _GUICtrlListView_Create

См. также

_GUICtrlListView_Create

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $GUI, $HandleBefore, $hListView

    $GUI = GUICreate("(UDF) Удаление ListView", 400, 300)

    $hListView = _GUICtrlListView_Create($GUI, "", 2, 2, 394, 268)
    $HandleBefore = $hListView
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_InsertColumn($hListView, 0, "Колонка 1", 100)
    _GUICtrlListView_InsertColumn($hListView, 1, "Колонка 2", 100)
    _GUICtrlListView_InsertColumn($hListView, 2, "Колонка 3", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1")
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1")
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1")

    MsgBox(4160, "Информация", "Удаление ListView по дескриптору: " & $hListView)
    MsgBox(4160, "Информация", "ListView удалён: " & _GUICtrlListView_Destroy($hListView) & @LF & _
            "Дескриптор перед удалением: " & $HandleBefore & @LF & _
            "Дескриптор после удаления: " & $hListView)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main