↑  ←  Описание функции

_GUICtrlListView_DeleteAllItems

Удаляет все пункты из ListView

#include <GuiListView.au3>
_GUICtrlListView_DeleteAllItems($hWnd)

Параметры

Возвращаемое значение

См. также

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Example1()
Example2()
Example_UDF_Created()

Func Example1()
    Local $hListView

    GUICreate("ListView - Удаляет все пункты", 400, 300)

    $hListView = GUICtrlCreateListView("Кол1|Кол2|Кол3", 2, 2, 394, 268)
    GUISetState()

    ; Загружает 3 колонки
    For $iI = 0 To 9
        GUICtrlCreateListViewItem("Пункт " & $iI & "|Пункт " & $iI & "-1|Пункт " & $iI & "-2", $hListView)
    Next

    MsgBox(4160, "Информация", "Удаляет все пункты")
    ; Пункты созданы используя встроенную функцию, с передачей идентификатора элемента
    MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteAllItems($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example1

Func Example2()
    Local $hListView, $aItems[10][3]

    GUICreate("ListView - Удаляет все пункты", 400, 300)

    $hListView = GUICtrlCreateListView("Кол1|Кол2|Кол3", 2, 2, 394, 268)
    GUISetState()

    ; Загружает 3 колонки
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Пункт " & $iI
        $aItems[$iI][1] = "Пункт " & $iI & "-1"
        $aItems[$iI][2] = "Пункт " & $iI & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)

    MsgBox(4160, "Информация", "Удаляет все пункты")
    ; Пункты созданы используя UDF функцию, с передачей дескриптор элемента
    MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($hListView)))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example2

Func Example_UDF_Created()
    Local $GUI, $hListView, $aItems[10][3]

    $GUI = GUICreate("ListView UDF - Удаляет все пункты", 400, 300)

    $hListView = _GUICtrlListView_Create($GUI, "Кол1|Кол2|Кол3", 2, 2, 394, 268)
    GUISetState()

    ; Загружает 3 колонки
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Пункт " & $iI
        $aItems[$iI][1] = "Пункт " & $iI & "-1"
        $aItems[$iI][2] = "Пункт " & $iI & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)

    MsgBox(4160, "Информация", "Удаляет все пункты")
    ; Это уже дескриптор
    MsgBox(4160, "Удалено?", _GUICtrlListView_DeleteAllItems($hListView))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example_UDF_Created