↑  ←  Описание функции

_GUICtrlListBox_Sort

Пересортировывает ListBox, если он имеет стиль $LBS_SORT

#include <GuiListBox.au3>
_GUICtrlListBox_Sort($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Пересортировывает ListBox, если он имеет стиль $LBS_SORT Может оказаться полезным при использовании InsertString

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $sText, $hListBox

    ; Создаёт GUI
    GUICreate("Сортирует ListBox", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_MULTIPLESEL, $LBS_SORT))
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        $sText = StringFormat("%03d : Рандомная строка ", Random(1, 100, 1))
        For $iX = 1 To Random(1, 20, 1)
            $sText &= Chr(Random(65, 90, 1))
        Next
        _GUICtrlListBox_AddString($hListBox, $sText)
    Next
    _GUICtrlListBox_InsertString($hListBox, "Это тест", 0) ; отсутствует авто-сортировка при вставке пункта
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Сортирует ListBox
    MsgBox(4160, "Информация", "Сортировать данные")
    _GUICtrlListBox_Sort($hListBox)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main