↑  ←  Описание функции

_GUICtrlListBox_SetColumnWidth

Устанавливает ширину всех колонок (в пикселях)

#include <GuiListBox.au3>
_GUICtrlListBox_SetColumnWidth($hWnd, $iWidth)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iWidth Ширина всех колонок в пикселях

Примечания

Для использования в ListBox со стилем $LBS_MULTICOLUMN

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListBox

    ; Создаёт GUI
    GUICreate("Устанавливает ширину всех колонок", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_MULTICOLUMN))
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 50
        _GUICtrlListBox_AddString($hListBox, StringFormat("Пункт %03d", $iI))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    Sleep(700)
    ; Устанавливает ширину всех колонок
    _GUICtrlListBox_SetColumnWidth($hListBox, 100)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main