↑  ←  Описание функции

_GUICtrlListBox_GetHorizontalExtent

Возвращает ширину горизонтального прокручивания в ListBox

#include <GuiListBox.au3>
_GUICtrlListBox_GetHorizontalExtent($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех: Возвращает ширину прокручивания в пикселях

Примечания

ListBox должен иметь стиль $WS_HSCROLL.

См. также

_GUICtrlListBox_SetHorizontalExtent

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListBox

    ; Создаёт GUI
    GUICreate("Получает ширину горизонтальной прокрутки", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
    GUISetState()

    ; Добавляет длинную строку
    _GUICtrlListBox_AddString($hListBox, "AutoIt v3 - бесплатный бейсикоподобный скриптовой язык предназначенный для автоматизации окон GUI.")

    ; Получает текущий горизонтальный размер
    MsgBox(4160, "Информация", "Горизонтальный размер: " & _GUICtrlListBox_GetHorizontalExtent($hListBox))

    _GUICtrlListBox_SetHorizontalExtent($hListBox, 500)

    ; Получает текущий горизонтальный размер
    MsgBox(4160, "Информация", "Горизонтальный размер: " & _GUICtrlListBox_GetHorizontalExtent($hListBox))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main