Функция _GUICtrlHeader

_GUICtrlHeader_GetItemRect

Возвращает прямоугольник ограничивающий указанный пункт

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemRect($hWnd, $iIndex)

Параметры

$hWnd	Дескриптор элемента
$iIndex	Индекс пункта, отсчёт от 0

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - X координата верхнего левого угла прямоугольника
        [1] - Y координата верхнего левого угла прямоугольника
        [2] - X координата правого нижнего угла прямоугольника
        [3] - Y координата правого нижнего угла прямоугольника

См. также

_GUICtrlHeader_GetItemRectEx

Пример

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

$Debug_HDR = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $hHeader, $aRect

; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hHeader = _GUICtrlHeader_Create ($hGUI)
_GUICtrlHeader_SetUnicodeFormat ($hHeader, True)
$iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Добавляет колонки
_GUICtrlHeader_AddItem ($hHeader, "Колонка 1", 100)
_GUICtrlHeader_AddItem ($hHeader, "Колонка 2", 100)
_GUICtrlHeader_AddItem ($hHeader, "Колонка 3", 100)
_GUICtrlHeader_AddItem ($hHeader, "Колонка 4", 100)

; Показывает прямоугольник 1-ой колонки
$aRect = _GUICtrlHeader_GetItemRect ($hHeader, 0)
MemoWrite("Координаты границ прямоугольника 1-ой колонки")
MemoWrite("левая .: " & $aRect[0])
MemoWrite("верхняя: " & $aRect[1])
MemoWrite("правая : " & $aRect[2])
MemoWrite("нижняя : " & $aRect[3])

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite