↑  ←  Описание функции

_GUICtrlHeader_GetItemFlags

Возвращает информацию флага пункта

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemFlags($hWnd, $iIndex)

Параметры

$hWnd Дескриптор элемента
$iIndex Индекс пункта, отсчёт от 0

Возвращаемое значение

Успех: Возвращает информацию флага пункта в виде комбинации следующих значений:
        1 - Отображает изображение из списка изображений
        2 - Текст будет читаться в противоположном направлении от текста в родительском окне
        4 - Рисует стрелку вниз на этом пункте
        8 - Рисует стрелку вверх на этом пункте

См. также

_GUICtrlHeader_SetItemFlags

Пример

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

$Debug_HDR = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hHeader = _GUICtrlHeader_Create ($hGUI)
    _GUICtrlHeader_SetUnicodeFormat ($hHeader, True)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет колонки
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 1", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 2", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 3", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Колонка 4", 100)

    ; Устанавливает флаги 1-ой колонки
    _GUICtrlHeader_SetItemFlags ($hHeader, 0, 4)

    ; Показывает флаги 1-ой колонки
    MemoWrite("Флаги 1-ой колонки: " & _GUICtrlHeader_GetItemFlags ($hHeader, 0))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite