_GUICtrlDTP_SetMCFont
Устанавливает шрифт календаря месяца
#include <GuiDateTimePicker.au3>
_GUICtrlDTP_SetMCFont($hWnd, $hFont [, $fRedraw = True])
Параметры
| $hWnd | Дескриптор элемента |
| $hFont |
Дескриптор шрифта, который будет установлен |
| $fRedraw |
[необязательный] Следует ли перерисовать элемент немедленно |
См. также
_GUICtrlDTP_GetMCFontПример
#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
$Debug_DTP = False ; Проверяет ClassName передаваемый в DTP функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGui, $tLOGFONT, $hFont, $hDTP
; Создаёт GUI
$hGui = GUICreate("Устанавливает шрифт календаря", 400, 300)
$hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
; $hDTP = _GUICtrlDTP_Create($hGui, 2, 6, 190)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Устанавливает формат строки
_GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")
; Создаёт новый шрифт для календаря
$tLOGFONT = DllStructCreate($tagLOGFONT)
DllStructSetData($tLOGFONT, "Height", 18)
DllStructSetData($tLOGFONT, "Weight", 400)
DllStructSetData($tLOGFONT, "FaceName", "Verdana")
; DllStructSetData($tLOGFONT, "FaceName", "Comic Sans MS")
$hFont = _WinAPI_CreateFontIndirect($tLOGFONT)
_GUICtrlDTP_SetMCFont($hDTP, $hFont)
; Получает дескриптор шрифта календаря
GUICtrlSetData($iMemo, "Дескриптор шрифта: " & "0x" & Hex(_GUICtrlDTP_GetMCFont($hDTP), 6) & @CRLF & _
"IsPtr = " & IsPtr(_GUICtrlDTP_GetMCFont($hDTP)) & @CRLF & _
"IsHwnd = " & IsHWnd(_GUICtrlDTP_GetMCFont($hDTP)), 1)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main