_GUICtrlDTP_SetMCColor
Устанавливает цвет указанного участка элемента
#include <GuiDateTimePicker.au3>
_GUICtrlDTP_SetMCColor($hWnd, $iIndex, $iColor)
Параметры
| $hWnd | Дескриптор элемента |
| $iIndex |
Указывает, какой цвет календаря необходимо установить: 0 - Цвет фона между месяцами 1 - Цвет текста дней указанного месяца 2 - Цвет фона в заголовке календаря и выбранный день 3 - Цвет текста в заголовке календаря и выбранный день 4 - Цвет фона календаря 5 - Цвет текста для дней, которые не принадлежат указанному месяцу |
| $iColor |
Цвет (BGR), который будет установлен для указанного участка |
Возвращаемое значение
| Успех: | Возвращает предыдущий цвет указанного участка |
| Ошибка: | Возвращает -1 |
См. также
_GUICtrlDTP_GetMCColorПример
#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <Constants.au3>
$Debug_DTP = False ; Проверяет ClassName передаваемый в DTP функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hDTP
; Создаёт GUI
GUICreate("Устанавливает цвет календаря", 400, 300)
$hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Устанавливает формат строки
_GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")
; Устанавливает цвет элементов календаря
_GUICtrlDTP_SetMCColor($hDTP, 1, 0x8BD4DF) ; текст дней
_GUICtrlDTP_SetMCColor($hDTP, 2, 0xA9D7E4) ; фон заголовка
_GUICtrlDTP_SetMCColor($hDTP, 3, 0x005894) ; текст заголовка
_GUICtrlDTP_SetMCColor($hDTP, 4, 0x3F3F3F) ; фон календаря
_GUICtrlDTP_SetMCColor($hDTP, 5, 0xB2C2A9) ; текст дней не принадлежащих месяцу
; цвет можно установить с помощью констант $CLR_MONEYGREEN и т.д.
; Получает цвет DTP
MemoWrite("Фон между месяцами: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 0), 6))
MemoWrite("Текст дней .......: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 1), 6))
MemoWrite("Фон заголовка ....: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 2), 6))
MemoWrite("Текст заголовка ..: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 3), 6))
MemoWrite("Фон календаря.....: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 4), 6))
MemoWrite("Текст прочих дней.: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 5), 6))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite