Функция _GUICtrlDTP

_GUICtrlDTP_GetSystemTimeEx

Возвращает выбранную дату и время

#include <GuiDateTimePicker.au3>
_GUICtrlDTP_GetSystemTimeEx($hWnd)

Параметры

$hWnd

Дескриптор элемента

Возвращаемое значение

Успех: Возвращает структуру $tagSYSTEMTIME

Примечания

@error может иметь значения:
$GDT_VALID, если информация о времени была успешно возвращена.
$GDT_NONE, если элемент имеет стиль $DTS_SHOWNONE и галочка не была установлена.
$GDT_ERROR, если произошла ошибка.

См. также

_GUICtrlDTP_GetSystemTime, _GUICtrlDTP_SetSystemTimeEx, $tagSYSTEMTIME

Пример

#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

$Debug_DTP = False ; Проверяет ClassName передаваемый в DTP функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo, $tDate

_Main()

Func _Main()
Local $hDTP

; Создаёт GUI
GUICreate("Получает дату и время", 400, 300)
$hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Устанавливает формат строки
_GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

; Устанавливает дату и время
$tDate = DllStructCreate($tagSYSTEMTIME)
DllStructSetData($tDate, "Year", @YEAR)
DllStructSetData($tDate, "Month", 8)
DllStructSetData($tDate, "Day", 19)
DllStructSetData($tDate, "Hour", 21)
DllStructSetData($tDate, "Minute", 57)
DllStructSetData($tDate, "Second", 34)
_GUICtrlDTP_SetSystemTimeEx($hDTP, $tDate)

; Получает дату и время
$tDate = _GUICtrlDTP_GetSystemTimeEx($hDTP)
MemoWrite("Выбранная дата : " & GetDateStr())
MemoWrite("Выбранное время: " & GetTimeStr())

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc   ;==>_Main

; Возвращает элементы даты
Func GetDateStr()
Return StringFormat("%02d/%02d/%04d", DllStructGetData($tDate, "Month"), DllStructGetData($tDate, "Day"), DllStructGetData($tDate, "Year"))
EndFunc   ;==>GetDateStr

; Возвращает элементы времени
Func GetTimeStr()
Return StringFormat("%02d:%02d:%02d", DllStructGetData($tDate, "Hour"), DllStructGetData($tDate, "Minute"), DllStructGetData($tDate, "Second"))
EndFunc   ;==>GetTimeStr

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite