Функция _GUICtrlComboBox

_GUICtrlComboBox_SetExtendedUI

Выберите либо интерфейс пользователя по умолчанию, либо расширенный

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetExtendedUI($hWnd [, $fExtended = False])

Параметры

$hWnd	Дескриптор или идентификатор элемента
$fExtended	[необязательный] Указывает, будет ли ComboBox использовать расширенный интерфейс пользователя

Возвращаемое значение

Успех:	Возвращает True
Ошибка:	Возвращает False

Примечания

По умолчанию, клавиша F4 открывает или закрывает выпадающий список, а DOWN ARROW изменяет текущий выбор.

В ComboBox с расширенным интерфейсом пользователя, клавиша F4 отключена, а нажатие кнопки DOWN ARROW открывает выпадающий список

См. также

_GUICtrlComboBox_GetExtendedUI

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
Local $hCombo

; Создаёт GUI
GUICreate("Устанавливает расширенный интерфейс", 400, 296)
$hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Добавляет файлы
_GUICtrlComboBox_BeginUpdate($hCombo)
_GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
_GUICtrlComboBox_EndUpdate($hCombo)

; Проверяет, расширенный ли интерфейс
MemoWrite("Расширенный ли интерфейс: " & _GUICtrlComboBox_GetExtendedUI($hCombo))

; Устанавливает расширенный интерфейс
_GUICtrlComboBox_SetExtendedUI($hCombo, True)

; Проверяет, расширенный ли интерфейс
MemoWrite("Расширенный ли интерфейс: " & _GUICtrlComboBox_GetExtendedUI($hCombo))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite