↑  ←  Описание функции

_GUICtrlComboBox_SetCueBanner

Sets the cue banner text that is displayed for the edit control of a combo box

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetCueBanner($hWnd, $sText)

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText String that contains the text

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

The cue banner is text that is displayed in the edit control of a combo box when there is no selection


Минимальная ОС: Windows Vista

См. также

_GUICtrlComboBox_GetCueBanner

Пример

If @osversion = "WIN_XP" And MsgBox(4160 + 4 + 256, "Информация", "Эта функция не работает в WinXP" & @lf & "продолжить?") = 7 Then Exit
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo
_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Устанавливает CueBanner", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    _GUICtrlComboBox_SetCueBanner($hCombo, "Select an Item")
    $iMemo = GUICtrlCreateEdit("", 10, 50, 376, 234, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    MemoWrite("Cue Banner: " & _GUICtrlComboBox_GetCueBanner($hCombo))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite