↑  ←  Описание функции

_GUICtrlComboBox_InsertString

Вставляет строку

#include <GuiComboBox.au3>
_GUICtrlComboBox_InsertString($hWnd, $sText [, $iIndex = -1])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Строка для вставки
$iIndex [необязательный] Указывает индекс позиции, в которую необходимо вставить строку, отсчёт от 0.

Возвращаемое значение

Успех:Возвращает индекс позиции, в которую вставлена строка
Ошибка:Возвращает -1

Примечания

Если параметр $iIndex = -1, то строка добавляется в конец списка.

Если ComboBox имеет стиль $WS_HSCROLL и вы вставляете строку шире чем ComboBox, то вы должны использовать функцию _GUICtrlComboBox_SetHorizontalExtent, чтобы обеспечить появление горизонтальной полосы прокрутки.

См. также

_GUICtrlComboBox_AddString, _GUICtrlComboBox_InitStorage

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Вставляет строку", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Вставляет строку
    _GUICtrlComboBox_InsertString($hCombo, "--- Вставленная строка ---", 0)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main