↑  ←  Описание функции

_GUICtrlComboBox_GetEditSel

Возвращает позиции начального и конечного символов текущего выделенного текста в поле ввода ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetEditSel($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - Позиция начального символа
        [1] - Позиция конечного символа
Ошибка: Возвращает -1

Примечания

Если сообщение высылается в ComboBox со стилем $CBS_DROPDOWN или $CBS_DROPDOWNLIST, то функция потерпит неудачу.

См. также

_GUICtrlComboBox_SetEditSel, _GUICtrlComboBoxEx_SetEditSel

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $aSel, $hCombo

    ; Создаёт GUI
    GUICreate("Получает позиции выделенного", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Выбирает пункт
    _GUICtrlComboBox_SetCurSel($hCombo, 2)

    ; Выделяет символы в поле ввода
    _GUICtrlComboBox_SetEditSel($hCombo, 0, 4)

    ; Получает позиции выделенного
    $aSel = _GUICtrlComboBox_GetEditSel($hCombo)
    MemoWrite(StringFormat("Позиции выделенного: %d - %d", $aSel[0], $aSel[1]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite