Функция _GUICtrlComboBox

_GUICtrlComboBox_FindString

Поиск строки, совпадающей с началом пункта

#include <GuiComboBox.au3>
_GUICtrlComboBox_FindString($hWnd, $sText [, $iIndex = -1])

Параметры

$hWnd	Дескриптор или идентификатор элемента
$sText	Строка для поиска
$iIndex	[необязательный] Индекс пункта, предшествующий пункту с которого начинается поиск. Отсчёт от 0.

Возвращаемое значение

Успех:	Возвращает индекс найденного пункта, отсчёт от 0.
Ошибка:	Возвращает -1

Примечания

Ищет совпадение от начала строки с символами указанными в $sText
Если поиск достигает конца списка, то продолжается с начала списка до пункта, указанного в $iIndex включительно.

Если $iIndex = -1, то поиск выполняется по всему списку с самого начала.

См. также

_GUICtrlComboBox_SelectString

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
Local $hCombo

; Создаёт GUI
GUICreate("Поиск совпадения от начала строки", 400, 296)
$hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
GUISetState()

; Добавляет файлы
_GUICtrlComboBox_BeginUpdate($hCombo)
_GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)
_GUICtrlComboBox_AddString($hCombo, 'Это тест')
_GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES)
_GUICtrlComboBox_EndUpdate($hCombo)

; Поиск строки
MsgBox(4160, "Информация", "Найдена строка: " & _GUICtrlComboBox_FindString($hCombo, "этО"))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main