↑  ←  Описание функции

_GUICtrlButton_GetImageList

Возвращает массив, характеризующий список изображений, назначенный кнопке

#include <GuiButton.au3>
_GUICtrlButton_GetImageList($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Дескриптор списка изображений
        [1] - Левый отступ иконки
        [2] - Верхний отступ иконки
        [3] - Правый отступ иконки
        [4] - Нижний отступ иконки
        [5] - Выравнивание. Это может быть одно из следующих значений:
            0 - Изображение выравнивается по левому краю.
            1 - Изображение выравнивается по правому краю.
            2 - Изображение выравнивается по верхнему краю.
            3 - Изображение выравнивается по нижнему краю.
            4 - Изображение по центру.

Примечания

Минимальная ОС - Windows XP.

См. также

_GUICtrlButton_SetImageList

См. также

Искать BCM_GETIMAGELIST в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiButton.au3>
#include <GuiImageList.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hImage, $y = 70, $iIcon = 125, $btn[6], $aImageListInfo

    GUICreate("Получает характеристики списка изображений", 510, 400)
    $iMemo = GUICtrlCreateEdit("", 119, 10, 376, 374, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create(32, 32, 5, 3, 6)
    For $x = 6 To 11
        _GUIImageList_AddIcon($hImage, "shell32.dll", $x, True)
    Next

    $btn[0] = GUICtrlCreateButton("Кнопка1", 10, 10, 90, 50)
    _GUICtrlButton_SetImageList($btn[0], $hImage)


    For $x = 1 To 5
        $btn[$x] = GUICtrlCreateButton("Кнопка" & $x + 1, 10, $y, 90, 50)
        _GUICtrlButton_SetImageList($btn[$x], _GetImageListHandle("shell32.dll", $iIcon + $x, True), $x)
        $y += 60
    Next


    For $x = 0 To 5
        $aImageListInfo = _GUICtrlButton_GetImageList($btn[$x])
        MemoWrite("Кнопка" & $x + 1 & " информация списка изображений" & @CRLF & "--------------------------------")
        MemoWrite("Дескриптор списка изображений: " & $aImageListInfo[0])
        MemoWrite("Левый отступ иконки: " & $aImageListInfo[1])
        MemoWrite("Верхний отступ иконки: " & $aImageListInfo[2])
        MemoWrite("Правый отступ иконки: " & $aImageListInfo[3])
        MemoWrite("Нижний отступ иконки: " & $aImageListInfo[4])
        MemoWrite("Выравнивание: " & _ExplainAlignment($aImageListInfo[5]))
        MemoWrite("--------------------------------" & @CRLF)
    Next

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Использование списка изображений, чтобы установить 1 изображение и текст на кнопке
Func _GetImageListHandle($sFile, $nIconID = 0, $fLarge = False)
    Local $iSize = 16
    If $fLarge Then $iSize = 32

    Local $hImage = _GUIImageList_Create($iSize, $iSize, 5, 3)
    If StringUpper(StringMid($sFile, StringLen($sFile) - 2)) = "BMP" Then
        _GUIImageList_AddBitmap($hImage, $sFile)
    Else
        _GUIImageList_AddIcon($hImage, $sFile, $nIconID, $fLarge)
    EndIf
    Return $hImage
EndFunc   ;==>_GetImageListHandle

Func _ExplainAlignment($iAlign)
    Switch $iAlign
        Case 0
            Return "Изображение выравнивается по левому краю."
        Case 1
            Return "Изображение выравнивается по правому краю."
        Case 2
            Return "Изображение выравнивается по верхнему краю."
        Case 3
            Return "Изображение выравнивается по нижнему краю."
        Case 4
            Return "Изображение по центру."
    EndSwitch
EndFunc   ;==>_ExplainAlignment