↑  ←  Описание функции

_GUICtrlButton_GetIdealSize

Возвращает размер кнопки наиболее подходящий к тексту и изображению, если список изображений установлен

#include <GuiButton.au3>
_GUICtrlButton_GetIdealSize($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Идеальная ширина
        [1] - Идеальная высота

Примечания

Минимальная ОС - Windows XP.

См. также

_GUICtrlButton_SetSize

См. также

Искать BCM_GETIDEALSIZE в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiButton.au3>
#include <GuiImageList.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hImage, $btn, $aIdealSize

    GUICreate("Подходящий размер кнопки", 400, 400)
    $iMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")

    $hImage = _GUIImageList_Create(32, 32, 5, 3, 6)
    For $x = 6 To 11
        _GUIImageList_AddIcon($hImage, "shell32.dll", $x, True)
    Next

    $btn = GUICtrlCreateButton("Кнопка1", 10, 10, 90, 50)
    _GUICtrlButton_SetImageList($btn, $hImage)

    GUISetState()

    $aIdealSize = _GUICtrlButton_GetIdealSize($btn)
    MemoWrite('Подходящие размеры Кнопка1 ' & @CRLF & ' ширина: ' & $aIdealSize[0] & @CRLF & ' высота: ' & $aIdealSize[1])

    Sleep(3000)

    MemoWrite(StringFormat("Устанавливает размер: %s", _GUICtrlButton_SetSize($btn, $aIdealSize[0], $aIdealSize[1])))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite