↑  ←  Описание функции

_GUICtrlButton_GetCheck

Возвращает флажок состояния радиокнопки или checkbox

#include <GuiButton.au3>
_GUICtrlButton_GetCheck($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает состояние кнопки, созданной с использованием стилей $BS_AUTOCHECKBOX, $BS_AUTORADIOBUTTON, $BS_AUTO3STATE, $BS_CHECKBOX, $BS_RADIOBUTTON или $BS_3STATE и может быть одно из следующих:
$BST_CHECKED - Кнопка с флажком (отмеченная галочкой, кружком).
$BST_INDETERMINATE - Третье состояние кнопки, указывающее неопределённое состояние (применяется только когда кнопка имеет стиль $BS_3STATE или $BS_AUTO3STATE).
$BST_UNCHECKED - Кнопка без флажка.
Ошибка:Возвращает 0

Примечания

Если кнопка не имеет ни одного из стилей перечисленных выше, то возвращаемое значение равно нулю.

См. также

_GUICtrlButton_GetState, _GUICtrlButton_SetCheck

См. также

Искать BM_GETCHECK в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $rdo, $rdo2, $chk

    GUICreate("Проверяет флажок", 400, 400)
    $iMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")

    $rdo = GUICtrlCreateRadio("Радио1", 10, 10, 90, 50)

    $rdo2 = GUICtrlCreateRadio("Радио2", 10, 60, 90, 50)
    _GUICtrlButton_SetCheck($rdo2)
    _GUICtrlButton_SetFocus($rdo2) ; устанавливает фокус, и показывает что это не влияет на _GUICtrlButton_GetCheck

    $chk = GUICtrlCreateCheckbox("Check1", 10, 120, 90, 50, BitOR($BS_AUTO3STATE, $BS_NOTIFY))
    _GUICtrlButton_SetCheck($chk, $BST_INDETERMINATE)

    GUISetState()

    MemoWrite("Состояние Радио1: " & _ExplainCheckState(_GUICtrlButton_GetCheck($rdo)) & @CRLF)
    MemoWrite("Состояние Радио2: " & _ExplainCheckState(_GUICtrlButton_GetCheck($rdo2)) & @CRLF)
    MemoWrite("Состояние Check1: " & _ExplainCheckState(_GUICtrlButton_GetCheck($chk)) & @CRLF)


    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

Func _ExplainCheckState($iState)
    Switch $iState
        Case $BST_CHECKED
            Return "Отмечена"
        Case $BST_INDETERMINATE
            Return "Серая, третье состояние, указывающее неопределённое состояние (применяется только когда кнопка имеет стиль $BS_3STATE или $BS_AUTO3STATE)."
        Case $BST_UNCHECKED
            Return "Не отмечена"
    EndSwitch
EndFunc   ;==>_ExplainCheckState