↑  ←  Описание функции

_GUICtrlAVI_Destroy

Удаляет элемент AVI

#include <GuiAVI.au3>
_GUICtrlAVI_Destroy(ByRef $hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает True, устанавливает дескриптор равным 0
Ошибка:Возвращает False

Примечания

Ограничение: применяется только к элементу AVI, созданному функцией _GUICtrlAVI_Create

См. также

_GUICtrlAVI_Create

Пример

#include <GUIConstantsEx.au3>
#include <GuiAVI.au3>

$Debug_AVI = False ; Проверяет ClassName передаваемый в AVI функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hAVI

_Main()

Func _Main()
    Local $Wow64 = ""
    If @autoitx64 Then $Wow64 = "\Wow6432Node"
    Local $hGUI, $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"

    ; Создаёт GUI
    $hGUI = GUICreate("(UDF) Удаляет элемент AVI", 300, 100)
    $hAVI = _GUICtrlAVI_Create ($hGUI, "", -1, 10, 10)
    GUISetState()

    ; Воспроизводит пример AutoIt AVI
    _GUICtrlAVI_Open ($hAVI, $sFile)

    ; Воспроизводит пример AutoIt AVI
    _GUICtrlAVI_Play($hAVI)

    Sleep(2000)  ; ожидание 2 секунды

    ; останавливает воспроизведение клипа
    _GUICtrlAVI_Stop ($hAVI)

    ; Закрывает AVI
    _GUICtrlAVI_Close ($hAVI)

    MsgBox(4160, "Информация", "Удаляет элемент AVI")
    _GUICtrlAVI_Destroy ($hAVI)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main