↑  ←  Описание функции

_GDIPlus_PenSetAlignment

Устанавливает выравнивание Карандаша

#include <GDIPlus.au3>
_GDIPlus_PenSetAlignment($hPen [, $iAlignment = 0])

Параметры

$hPen Дескриптор объекта Карандаш
$iAlignment [необязательный] Выравнивание Карандаша. Может быть одним из следующих значений:
    0 - Карандаш выравнивается по центру рисуемой линии
    1 - В случае рисования многоугольника Карандаш выравнивается по внутреннему краю многоугольника

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GDIPlus_PenGetAlignment

См. также

Искать GdipSetPenMode в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Создаёт ресурсы
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate (0xFF000000, 4)
    _GDIPlus_PenSetEndCap ($hPen, $GDIP_LINECAPARROWANCHOR)
    _GDIPlus_PenSetAlignment ($hPen, 1)

    ; Show pen alignment
    MsgBox(4096, "Информация", "Pen alignment: " & _GDIPlus_PenGetAlignment ($hPen))

    ; Рисует стрелки
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 130, 390, 130, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 6)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 8)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 170, 390, 170, $hPen)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main