↑  ←  Описание функции

_GDIPlus_ImageGetPixelFormat

Возвращает пиксельный формат изображения: бит на пиксель, альфа-каналы, RGB, градации серого, индексированное т.д.

#include <GDIPlus.au3>
_GDIPlus_ImageGetPixelFormat($hImage)

Параметры

$hImage Дескриптор объекта изображения

Возвращаемое значение

Успех:Возвращает массив следующего формата:
[0] - - Константа пиксельного формата в виде целого числа
[1] - - Пиксельный формат в виде строки
Ошибка:Возвращает пустой массив и устанавливает @error, @extended содержит местную ошибку функции
@error:0 - Нет ошибок.
10 - Неверный дескриптор изображения

Примечания

@error 4 основывается на возвращении функцией GDI+ UDF значений -1 или 0, как ошибка, вместо возвращения дескриптора изображения

См. также

_GDIPlus_ImageGetFlags, _GDIPlus_BitmapLockBits, _GDIPlus_BitmapCloneArea

См. также

Искать GdipGetImagePixelFormat в библиотеке MSDN

Пример


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>


Global $iMemo

_Main()

Func _Main()
    Local $hBitmap, $hImage, $aRet

    ; Создаёт GUI
    GUICreate("GDI+", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Инициализация библиотеки GDI+
    _GDIPlus_Startup()

    ; Capture 32 bit bitmap
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; Show pixel format for screen capture
    $aRet = _GDIPlus_ImageGetPixelFormat($hImage)
    MemoWrite("Image pixel format of screen capture: " & $aRet[1]);
    MemoWrite("Image pixel format constant: " & $aRet[0]);
    MemoWrite();

    ; Save screen capture bitmap to file
    _GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Очищает ресурсы
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; Load screen capture bitmap from file
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Show pixel format for saved file
    $aRet = _GDIPlus_ImageGetPixelFormat($hImage)
    MemoWrite("Image pixel format of saved file: " & $aRet[1]);
    MemoWrite("Image pixel format constant: " & $aRet[0]);

    ; Очищает ресурсы
    _GDIPlus_ImageDispose($hImage)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = '')
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite