↑  ←  Описание функции

_GDIPlus_ImageGetHorizontalResolution

Возвращает горизонтальное разрешение изображения в DPI (пиксель на дюйм)

#include <GDIPlus.au3>
_GDIPlus_ImageGetHorizontalResolution($hImage)

Параметры

$hImage Дескриптор объекта изображения

Возвращаемое значение

Успех:Возвращает целое число DPI (пиксель на дюйм)
Ошибка:Возвращает 0 и устанавливает @error
@error:0 - нет ошибки.
10 - Неверный дескриптор изображения

Примечания

@error 4 основывается на возвращении функцией GDI+ UDF значений -1 или 0, как ошибка, вместо возвращения дескриптора изображения

См. также

_GDIPlus_ImageGetVerticalResolution

См. также

Искать GdipGetImageHorizontalResolution в библиотеке MSDN

Пример


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>


Global $iMemo

_Main()

Func _Main()
    Local $hBitmap, $hImage

    ; Создаёт GUI
    GUICreate("GDI+", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Инициализация библиотеки GDI+
    _GDIPlus_Startup()

    ; Capture 32 bit bitmap
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; Show horizontal resolution in DPI (dots per inch) of image
    MemoWrite("HorizontalResolution DPI : " & _GDIPlus_ImageGetHorizontalResolution($hImage));

    ; Очищает ресурсы
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = '')
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite