↑  ←  Описание функции

_GDIPlus_GraphicsDrawPolygon

Рисует многоугольник

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawPolygon($hGraphics, $aPoints [, $hPen = 0])

Параметры

$hGraphics Дескриптор графического объекта
$aPoints Массив, точек являющихся вершинами многоугольника:
    [0][0] - Количество точек-вершин
    [1][0] - X-координата точки-вершины 1
    [1][1] - Y-координата точки-вершины 1
    [2][0] - X-координата точки-вершины 2
    [2][1] - Y-координата точки-вершины 2
    [n][0] - X-координата точки-вершины n
    [n][1] - Y-координата точки-вершины n
$hPen [необязательный] Дескриптор объекта карандаша, который используется для рисования многоугольника. Если 0, то чёрная линия шириной 1 пиксель.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если первая и последняя точка не совпадают по координатам, то между ними образуется линия, завершающая многоугольник.

См. также

Искать GdipDrawPolygonI в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $aPoints[4][2]

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Рисует многоугольник
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)

    $aPoints[0][0] = 3
    $aPoints[1][0] = 150
    $aPoints[1][1] = 150
    $aPoints[2][0] = 200
    $aPoints[2][1] = 100
    $aPoints[3][0] = 250
    $aPoints[3][1] = 150

    _GDIPlus_GraphicsDrawPolygon ($hGraphic, $aPoints)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_Shutdown ()

EndFunc   ;==>_Main