Функция _Date_Time_SystemTimeToTzSpecificLocalTime

_Date_Time_SystemTimeToTzSpecificLocalTime

Преобразует время UTC в локальное время с соответствующим часовым поясом

#include <Date.au3>
_Date_Time_SystemTimeToTzSpecificLocalTime($pUTC [, $pTimeZone = 0])

Параметры

$pUTC	Указатель на структуру $tagSYSTEMTIME, которая содержит время в UTC. Функция преобразует это время в локальное время указанного часового пояса.
$pTimeZone	[необязательный] Указатель на структуру $tagTIME_ZONE_INFORMATION, которая определяет интересующий часовой пояс. Если 0, то функция использует текущий активный часовой пояс.

Возвращаемое значение

Возвращает $tagSYSTEMTIME, содержащий локальное время

См. также

Пример

#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $tLocal, $tSystem

; Создаёт GUI
$hGUI = GUICreate("Время", 400, 300)
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Преобразует системное время в локальное время
$tSystem = _Date_Time_GetSystemTime()
$tLocal = _Date_Time_SystemTimeToTzSpecificLocalTime(DllStructGetPtr($tSystem))
MemoWrite("Системное время в локальное время .: " & _Date_Time_SystemTimeToDateTimeStr($tLocal ))

$tLocal = _Date_Time_GetLocalTime()
$tSystem = _Date_Time_TzSpecificLocalTimeToSystemTime(DllStructGetPtr($tLocal))
MemoWrite("Локальное время в системное время .: " & _Date_Time_SystemTimeToDateTimeStr($tSystem))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite