↑  ←  Описание функции

_ClipBoard_SetData

Помещает данные в буфер обмена в указанном формате

#include <Clipboard.au3>
_ClipBoard_SetData($vData [, $iFormat = 1])

Параметры

$vData Данные в бинарном или строковом формате или опционально NULL (0) (владелец должен предоставить, смотрите ниже).
    ВАЖНО: Если переданная строка не является типом $CF_TEXT, $CF_OEMTEXT, или $CF_UNICODETEXT, то это будет рассматриваться как ANSI-строка. Чтобы принудительно использовать Unicode строку для других типов данных, вы должны передать данные в бинарном формате. Также, НЕ следует передавать данные с типом $CF_UNICODETEXT в бинарном формате (это искажает данные).
    При $vData равным NULL, это означает, что окно предоставляет данные в заданном формате буфера обмена после запроса.
    Если окно задерживает его представление, оно должно обработать сообщения $WM_RENDERFORMAT и $WM_RENDERALLFORMATS. Если функция выполнена успешно, то система становится владельцем объекта идентифицирующегося параметром $hMemory. Приложение не может записать или освободить данные после того, как система стала владельцем, но может заблокировать и прочитать из данных пока не будет вызвана функция _ClipBoard_Close. Память должна быть разблокирована до закрытия буфера обмена. Если параметр $hMemory идентифицирует объект в памяти, то объект должен быть помещен, используя функцию с флагом $GMEM_MOVEABLE.
$iFormat [необязательный] Указывает формат буфера обмена:
    $CF_TEXT - Текстовый формат
    $CF_BITMAP - Дескриптор растрового рисунка (HBITMAP)
    $CF_METAFILEPICT - Дескриптор метафайла рисунка (METAFILEPICT)
    $CF_SYLK - Формат Символической Связи Microsoft (SYLK)
    $CF_DIF - Формат обмена данными программы Arts'
    $CF_TIFF - Формат файла тегированного изображения
    $CF_OEMTEXT - Текстовый формат, содержащий символы в OEM наборе символов
    $CF_DIB - Структура BITMAPINFO, сопровождаемая растровыми битами
    $CF_PALETTE - Дескриптор цветовой палитры
    $CF_PENDATA - Данные для пера для Pen Computing (Компьютерного пера).
    $CF_RIFF - Звуковые данные в формате RIFF
    $CF_WAVE - Звуковые данные в формате WAVE
    $CF_UNICODETEXT - Текстовый формат в юникоде
    $CF_ENHMETAFILE - Дескриптор улучшенного метафайла (HENHMETAFILE)
    $CF_HDROP - Дескриптор типа HDROP, идентифицирующий список файлов
    $CF_LOCALE - Дескриптор локального идентификатора, связанного с текстом в буфере обмена
    $CF_DIBV5 - Структура BITMAPV5HEADER, сопровождаемая растровыми цветами и растровыми битами
    $CF_OWNERDISPLAY - Собственный формат отображения данных
    $CF_DSPTEXT - Формат отображения текста, связанный с собственным форматом
    $CF_DSPBITMAP - Растровый формат отображения, связанный с собственным форматом
    $CF_DSPMETAFILEPICT - Формат отображения данных метафайла-картинки, связанного с собственным форматом
    $CF_DSPENHMETAFILE - Формат отображения улучшенного метафайла связанного с собственным форматом

Возвращаемое значение

Успех:Возвращает дескриптор данных
Ошибка:Возвращает 0

Примечания

Эта функция выполняет все шаги, необходимые для помещения данных в буфер обмена. Эти шаги: помещения глобального объекта памяти, открытия буфера обмена, помещения данных в буфер обмена и закрытие буфера обмена. Если необходимо больше возможностей для управления помещением данных в буфер обмена, то используйте функцию _ClipBoard_SetDataEx.

См. также

_ClipBoard_GetData, _ClipBoard_SetDataEx, _ClipBoard_Empty, _ClipBoard_GetDataEx

Пример

#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $btn_SetData, $btn_GetData

    ; Создаёт GUI
    $hGUI = GUICreate("Clipboard", 600, 450)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    $btn_SetData = GUICtrlCreateButton("Вставить в буфер обмена", 120, 410, 160, 30)
    $btn_GetData = GUICtrlCreateButton("Получить из буфера обмена", 320, 410, 160, 30)
    GUISetState()

    ; Цикл выполняется, пока окно не будет закрыто
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btn_SetData
                _ClipBoard_SetData("Текст для буфера обмена")
            Case $btn_GetData
                GUICtrlSetData($iMemo, _ClipBoard_GetData() & @CRLF, 1)
        EndSwitch
    WEnd

EndFunc   ;==>_Main