↑  ←  Описание функции

_ClipBoard_GetFormatName

Возвращает имя указанного зарегистрированного формата

#include <Clipboard.au3>
_ClipBoard_GetFormatName($iFormat)

Параметры

$iFormat Тип формата

Возвращаемое значение

Успех:Возвращает имя формата
Ошибка:Возвращает пустую строку

Примечания

Параметр $iFormat не должен указывать на какой либо встроенный формат буфера обмена

См. также

Искать GetClipboardFormatNameA в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $iFormat

    ; Создаёт GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Регистрирует новый формат буфера обмена
    $iFormat = _ClipBoard_RegisterFormat("AutoIt Library Text")
    If $iFormat <> 0 Then
        ; Показывает новый формат
        MemoWrite(_ClipBoard_GetFormatName($iFormat))
    Else
        _WinAPI_ShowError("Ошибка функции _ClipBoard_RegisterFormat")
    EndIf

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite