_ArrayDisplay
Отображает одномерный или двумерный массив в ListView.
#include <Array.au3>
_ArrayDisplay(Const ByRef $avArray [, $sTitle = "Array: ListView Display" [, $iItemLimit = -1 [, $iTranspose = 0 [, $sSeparator = "" [, $sReplace = "|" [, $sHeader = ""]]]]]])
Параметры
| $avArray | Массив для отображения |
| $sTitle |
[необязательный] Заголовок окна, в котором отображается массив |
| $iItemLimit |
[необязательный] Максимальное количество отображаемых пунктов (строк) ListView |
| $iTranspose |
[необязательный] Если не 0, которое по умолчанию, то трансформировать отображение массива, поменяв местами колонки со строками |
| $sSeparator |
[необязательный] Изменить Opt("GUIDataSeparatorChar") на лету |
| $sReplace |
[необязательный] Строка заменяющая любой $sSeparator в каждом элементе массива |
| $sheader |
[необязательный] Названия колонок (колонки заголовков разделяются '|') |
Возвращаемое значение
| Успех: | Возвращает 1 |
| Ошибка: | Возвращает 0, устанавливает @error: |
| @error: | 1 - Массив $avArray не является массивом |
| 2 - Размерность массива $avArray более двух (поддерживается не более 2) |
Пример
#include <Array.au3>
;===============================================================================
; Пример 1
;===============================================================================
$asControls = StringSplit(WinGetClassList("[active]", ""), @LF)
_ArrayDisplay($asControls, "Список классов активного окна")
;===============================================================================
; Пример 2 (использование массива, определяемого вручную)
;===============================================================================
Local $avArray[10]
$avArray[0] = "JPM"
$avArray[1] = "Holger"
$avArray[2] = "Jon"
$avArray[3] = "Larry"
$avArray[4] = "Jeremy"
$avArray[5] = "Valik"
$avArray[6] = "Cyberslug"
$avArray[7] = "Nutster"
$avArray[8] = "JdeB"
$avArray[9] = "Tylo"
_ArrayDisplay($avArray, "$avArray - заданный вручную 1D массив")
_ArrayDisplay($avArray, "$avArray - заданный вручную 1D массив, транспонированный", -1, 1)
;===============================================================================
; Пример 3 (использование массива возвращённого функцией StringSplit())
;===============================================================================
$avArray = StringSplit(WinGetClassList("", ""), @LF)
_ArrayDisplay($avArray, "$avArray в виде списка классов окна")
;===============================================================================
; Пример 4 (2D массив)
;===============================================================================
Local $avArray[2][5] = [["JPM", "Holger", "Jon", "Larry", "Jeremy"], ["Valik", "Cyberslug", "Nutster", "JdeB", "Tylo"]]
_ArrayDisplay($avArray, "$avArray в виде 2D массива")
_ArrayDisplay($avArray, "$avArray в виде 2D массива, транспонированный", -1, 1)
_ArrayDisplay($avArray, "Задаёт имя колонки", -1, 1, '', '|', '№|Имя 1|Имя 2')
; Универсальный вариант с именами столбцов, в случае проблем.
; $s = Chr(1)
; _ArrayDisplay($avArray, "Задаёт имя колонки", -1, 0, $s, $s, '№' & $s & 'Имя 1' & $s & 'Имя 2')