↑  ←  Описание функции

GUISwitch

Переключает текущее окно, используемое для функций GUI.

GUISwitch ( winhandle [, tabitemID ] )

Параметры

winhandle Дескриптор окна для переключения.
tabitemID [необязательный] Идентификатор элемента TabItem, который должен быть выбран.

Возвращаемое значение

Успех:Возвращает дескриптор предыдущего окна
Ошибка:Возвращает NULL дескриптор.

Примечания

Многие специальные функции GUI работают с текущим окном - обычно это последнее окно, созданное функцией GUICreate. Эта функция позволяет вам сделать другое окно текущим. Это не означает, что выбранное окно станет активным. Для этого используйте WinActivate().

Использование параметра tabitemID позволяет создать новый элемент на указанной вкладке. Не забудьте завершить такой вызов функцией GUICtrlCreateTabItem("")

См. также

GUICreate, GUIDelete, GUICtrlCreateTabItem

Пример

$hGui1 = GUICreate("Окно 1")
GUICtrlCreateTab(10, 10)
$tabitem = GUICtrlCreateTabItem("Вкладка 1")
GUICtrlCreateTabItem("Вкладка 2")
GUICtrlCreateTabItem("")
$iButton = GUICtrlCreateButton('Добавить кнопку на вкладку', 220, 90, 160, 28)
GUISetState()

$hGui2 = GUICreate("Окно 2", -1, -1, 30)
GUISetState()

GUISwitch($hGui1) ; делает "Окно 1" текущим
GUISetBkColor(0xbddada) ; цвет применяется к текущему окну, если не указан дескриптор

While 1
    Switch GUIGetMsg()
        Case $iButton
            ; Добавляет кнопку на вкладку
            GUISwitch($hGui1, $tabitem)
            GUICtrlCreateButton("OK", 50, 90, 50)
            GUICtrlCreateTabItem("")
        Case -3
            Exit
    EndSwitch
WEnd