↑  ←  Описание функции

GUICtrlSetColor

Устанавливает цвет текста элемента.

GUICtrlSetColor ( controlID, textcolor )

Параметры

controlID Идентификатор элемента возвращаемый функцией GUICtrlCreate....
textcolor Цвет в формате RGB (шестнадцатеричного или десятичного числа).

Возвращаемое значение

Успех:Возвращает 1.
Ошибка:Возвращает 0.

Примечания

Устанавливается только для элементов Button, Label, Checkbox, Group, Radio, Edit, Input, List, Listview, ListviewItem, Treeview, TreeviewItem, Graphic, Progress и Combo.

Элементы Checkbox, Radio, Group, Progress, Combo могут быть окрашены, если используется классический стиль.

Кнопки всегда окрашиваются в классический стиль Windows.

См. также

GUICtrlCreate..., GUICtrlSetBkColor, GUICtrlSetDefColor

Пример

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $msg, $iChBox

    GUICreate("Мой GUI с цветным текстом") ; Создаёт окно в центре экрана

    GUICtrlCreateLabel("Красный текст", 10, 20)
    GUICtrlSetColor(-1, 0xff0000) ; Красный

    ; Способ окрасить элементы, которые окрашиваются только в классическом стиле
    GUICtrlCreateGroup("Зелёная группа", 10, 60, 180, 70)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", 0, "wstr", 0)
    GUICtrlSetColor(-1, 0x008800)

    GUISetFont(12, 400, 0, "Comic Sans MS") ; "Times New Roman"
    $iChBox = GUICtrlCreateCheckbox("Синий чекбокс", 20, 90, -1, 20)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($iChBox), "wstr", 0, "wstr", 0)
    GUICtrlSetColor(-1, 0x0000FF)
    GUICtrlSetBkColor(-1, 0xCCFFCC)

    GUISetState()

    ; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc